Chương 1: Phần cứng

Phần 1: Những mối hàn đầu tiên

Bắt đầu luôn với chút kinh nghiệm được rút ra từ đau thương.

Phần 2: "Hello World!!!"

Giống như lập trình phần mềm. Lập trình nhúng cũng có những bài "Hello world!!!".

Trong phần này ngoài thực hiện log lên màn hình dòng "Hello world!!!" chúng ta sẽ thêm một chút liên quan đến phần cứng là điều khiển đèn led trên ESP32

Cấu hình Dự án

Để cấu hình chúng ta sử dụng file platformio.ini 

[env:esp32-c3-devkitm-1]
platform = espressif32                    ; Khai báo nền tảng sử dụng
board = esp32-c3-devkitm-1                ; Khai báo board, thay đổi với những board khác nhau
framework = arduino                       ; Khai báo framework
lib_deps =                                ; Khai báo thư viện
	SPI                                   ;  với "hello world" thì chưa cần đến thư viện nào
	SD                                    ;  có thể xóa bỏ lib_deps nếu chưa dùng đến
monitor_speed = 115200                    ; Khai báo tốc độ giao tiếp Serial Monitor
build_flags =                             ; Tương tự như Scripting Define Symbols trong Unity
	-D ARDUINO_USB_MODE=1                 ;  cần 2 báo 2 trường tương tự như trong ví dụ 
	-D ARDUINO_USB_CDC_ON_BOOT=1          ;  để có thể xem được log

Các hàm cơ bản

// Một file main.cpp cơ bản khi làm việc với ESP32

#include <Arduino.h> // Khai báo thư viện

// Tương tự như Awake trong Unity.
// Hàm này được gọi 1 lần khi ESP32 khởi động.
// Dùng để khởi tạo, setup...
void setup() 
{
}

// Tương tự như hàm Update trong Unity
// Lặp lại mỗi khi các lệnh bên trong loop được thực hiện hết
void loop()
{
}

"Hello World!!!"

#include <Arduino.h>

// Khai báo chân giao tiếp với đèn led
const int LED_PIN = 8;

void setup() 
{
  // Setup chân led là output
  pinMode(LED_PIN, OUTPUT);

  // Khởi tạo serial có tốc độ trùng với tốc độ đã khai báo ở platformio.ini
  Serial.begin(115200);
  // Chờ đến khi serial khởi tạo xong hoặc hết thời gian chờ
  unsigned long start = millis();
  while (!Serial && millis() - start < 2000)
  {
    delay(1);
  }

  // Delay 1s để cửa sổ Serial Monitor kịp bật lên và nhìn thấy log
  // Nếu không có thì code vẫn chạy được nhưng của sổ Serial Monitor bật lên sau sẽ không nhìn thấy log
  delay(1000);

  // Hello world đây rồi =)))
  Serial.println("Hello world!!!");
}

void loop()
{
  digitalWrite(LED_PIN, LOW);   // Bật đèn LED
  delay(100);                   // Chờ 0.1 giây
  digitalWrite(LED_PIN, HIGH);  // Tắt đèn LED
  delay(100);                   // Chờ 0.1 giây
}

Sau khi code xong thì thực hiện

image.png

Chờ đến khi code được nạp xong. Nhìn cửa sổ terminal và mong chờ kết quả:

Hành trình fix bug đầu tiên

Vấn đề

Mặc dù đã nạp code thành công. Đèn nguồn có sáng nhưng tôi không nhận được bất kỳ dòng log nào dù có viết Serial.println("Hello world!!!"); ở setup() hay loop()

Quá trình debug

Kiểm tra chip

Để đảm bảo ESP32 này không chết trong lúc mình hàn. Nên mình đã dùng code điều khiển led để kiểm tra xem nó có còn hoạt động bình thường không.

Rất mừng là nó còn sống. Trước đấy vừa chết một con xong (T.T)

=> Vấn đề có thể do giao tiếp Serial qua USB

Kiểm tra các lỗi cấu hình

Đảm bảo tốc độ monitor_speed = 115200 là trùng nhau trong platformio.ini và main.cpp

Thử delay trước khi khởi tạo Serial.begin(115200);

Nhưng vấn đề vẫn không được giải quyết.

=> Có thể vấn đề do driver

Kiểm tra các môi trường khác

Chuyển sang macOS và sử dụng CLion với PlatformIO => Vẫn không được!!!

Dùng Ardruino IDE để code và nạp code => Code đã chạy và monitor đã hiện log.

=> Vấn đề có thể do cấu hình

Mấu chốt

So sánh 2 cách cấu hình thì trên Ardruino IDE có USB CDC On Boot: "Enabled".

Tương tự thêm build_flags -D ARDUINO_USB_CDC_ON_BOOT=1 vào platformio.ini thì sẽ gặp lỗi biên dịch của Serial. Cần phải thêm cả cờ -D ARDUINO_USB_MODE=1.

Lúc này vấn đề đã được giải quyết.

Giải thích

Mạch ESP32 - C3 SuperMini đang dùng sử dụng Native USB. Nghĩa là con chip sẽ tự mình xử lú giao tiếp USB. Để tính năng này hoạt động đúng thì trình biên dịch cần thực hiện 2 việc:

Phần 3: Màn hình

Ok, đầu tiên mình muốn chọn lắp màn hình trước.

Màn hình là phần giúp hiển thị trực quan nhất. Mình có thể thấy được thành quả của mình hiển thị ngay trên màn hình chứ không phải chỉ ở mỗi Serial.print

Màn hình cũng giúp mình kiểm tra được những lỗi phần cứng mà chỉ dùng Serial.print thì không thể tìm ra hết được.

Lắp đặt

Màn hình

ESP32-C3

Chắc năng

Lý do

Ghi Chú

VCC

3.3V hoặc 5V

Cấp nguồn cho màn hình.

Nguồn vào từ USB qua ESP32 có thể đẩy ra thành 2 nguồn 3.3V hoặc 5V.

Với những thiết bị nhẹ điện. Có thể sử dụng nguồn từ ESP32.

Chọn nguồn phù hợp với thiết bị

GND

GND

Nối đất

Tạo một điểm tham chiếu chung cho toàn bộ thiết bị trên hệ thống

Toàn bộ thiết bị đều cần kết nối GND

SCK

GPIO4

Clock (SPI)

Màn hình sử dụng giao thức SPI nên cần sử dụng chân clock
GPIO4 là chân clock của mạch ESP32-C3 này

Chân clock có thể thay đổi với những board mạch khác nhau. Kiểm tra datasheet để biết thêm chi tiết.

SDA

GPIO6

Data out (MOSI)

Màn hình nhận dữ liệu từ cổng ra của ESP32

MOSI cũng là một chân đặc biệt trên ESP32. Chú ý kiểm tra datasheet

RES

GPIO1

Reset

Là chân điều khiển không yêu cầu tốc độ cao. Chọn bất kỳ chân GPIO còn trống thuận tiện cho đi dây

Tránh chọn các chân đặc biệt
Cần chú ý khai báo chính xác trong code

DC

GPIO2

Data/Command

Tương tự như RES. Có thể chọn chân GPIO thuận tiện


BLK

GPIO3

Điều khiển nền của màn hình

Tương tự như RES và DC. Có thể chọn chân thuận tiện cho việc đi dây


Kiểm tra

Cài đặt thư viện TFT_eSPI

Arduino and PlatformIO IDE compatible TFT library optimised for the Raspberry Pi Pico (RP2040), STM32, ESP8266 and ESP32 that supports different driver chips

Để thêm thư viện chúng ta có thể thực hiện 1 trong 2 cách sau:

Khi đó file platformio.ini sẽ trông như thế này

[env:esp32-c3-devkitm-1]
platform = platformio/espressif32 @ 6.6.0
board = esp32-c3-devkitm-1
framework = arduino
platform_packages =
  framework-arduinoespressif32 @ ~3.20014.0
lib_deps = 
	SPI
	bodmer/TFT_eSPI@^2.5.43
monitor_speed = 115200
build_flags = 
	-D ARDUINO_USB_MODE=1
	-D ARDUINO_USB_CDC_ON_BOOT=1

Tiếp theo cần cấu hình thư viện để nó tương thích với đúng phần cứng.

Truy cập .pio → libdeps → esp32-c3-devkitm-1 → TFT_eSPI → User_Setup.h và thực hiện config tương ứng với cấu hình phần cứng.

// Driver của màn hình
#define ST7789_DRIVER
#define ESP32_C3_DMA_ERROR_WORKAROUND
#define TFT_RGB_ORDER TFT_RGB // Nếu màu in ra bị sai Blue và Red thì đổi lại thành TFT_BGR

// Kích thước của màn hình
#define TFT_WIDTH 240
#define TFT_HEIGHT 240

// Các chân kết nối đang được sử dụng
#define TFT_MOSI 6
#define TFT_SCLK 4
#define TFT_CS   -1

#define TFT_DC   2
#define TFT_RST  1
#define TFT_BL   3

// Tín hiệu bật/tắt đèn nền
#define TFT_BACKLIGHT_ON HIGH

// Các font sẽ được compile
#define LOAD_GLCD    // Font 1 (built-in), required for basic text
#define LOAD_FONT2   // Small 16 px font
#define LOAD_FONT4   // Medium 26 px font
#define LOAD_FONT6
#define LOAD_FONT7
#define LOAD_FONT8
#define LOAD_GFXFF  // FreeFonts (optional)
#define SMOOTH_FONT // Anti-aliased fonts (needs FS)

// Tốc độ SPI
#define SPI_FREQUENCY       40000000
#define SPI_READ_FREQUENCY  20000000

Cách này có điểm yếu là sẽ bị reset khi Full Clean hoặc Update/Re-install thư viện. Nhưng trong quá trình test các các setup khác đều gặp lỗi bootloop do config sai. Nên hiện tại vẫn sử dụng cách này để setup.

"Hello World!"

Tiếp theo để test xem màn hình đã được setup đúng và phần cứng còn hoạt động tốt hay không. Chúng ta sẽ thử với đoạn code hiển thị "Hello world!" trên màn hình.

Truy cập src → main.cpp và sử dụng đoạn code dưới đây:

#include <Arduino.h>
#include <TFT_eSPI.h>

// Tạo đối tượng tft từ thư viện
TFT_eSPI tft = TFT_eSPI();

void setup() {
  tft.init(); // Khởi tại tft controller

  tft.setRotation(0); // Set hướng xoay màn hình // Sử dụng các tham số 0, 1, 2, 3
  tft.fillScreen(TFT_BLACK); // Fill toàn bộ màn hình bằng màu đen
  tft.setTextColor(TFT_GREEN); // Set màu chữ
  tft.setTextSize(2); // Set cỡ chữ
  tft.setCursor(0, 0); // Set tọa độ điểm bắt đầu viết chữ
  tft.println("Hello World!"); // Hiển thị chữ
}

void loop() {}

Sau đó thực hiện Upload. Quá trình Upload có thể có warning (console màu vàng) nhưng không ảnh hưởng gì.

Sau khi upload xong kiểm tra màn hình nếu hiển thị như hình dưới là đã chạy thành công sẵn sàng cho bước tiếp theo thôi.1000048881.jpg

Trong trường hợp chưa hiển thị được "Hello World!" trên màn hình hãy kiểm tra cửa sổ terminal trên VSCode:

Nếu vẫn không được thực hiện check list sau:

Nếu vẫn không được nữa. Thì nên thử với một cái màn hình khác để đảm bảo phần cứng không bị hỏng.




Phần 4: Thẻ nhớ

Ok tiếp theo là lắp đặt thẻ nhớ.

Trong dự án này thẻ nhớ sẽ là nơi lưu trữ dữ liệu chính như hình gif, audio...

Trước khi bắt đầu thì có một điều cần chú ý

Xử lý conflict phần cứng

Thẻ nhớ sử dụng giao tiếp SPI. Với ESP32 khi sử dụng nhiều thiết bị giao tiếp chung SPI thì cần có chân CS để điều khiển.

Trong trường hợp hiện tại chúng ta có 2 thiết bị giao tiếp SPI là thẻ nhớ và màn hình. Khi cần giao tiếp với thẻ nhớ thì tín hiệu CS trên thẻ nhớ được bật và tắt đối với màn hình.

Thế nhưng trong phần trước. Màn hình chúng ta sử dụng có 7 pin và không có chân CS. Điều này là do chân CS được nhà sản xuất nối trực tiếp với GND. Tín hiệu CS trên màn hình sẽ luôn ở trạng thái bật. Vì vậy chúng ta có 2 hướng giải quyết:

ESP32_TheCube_Phan4_1.pngESP32_TheCube_Phan4_2.pngESP32_TheCube_Phan4_3.png

Ok vậy là xong. Đừng làm chết màn hình là được :)))

Lắp đặt

Màn hình

ESP32-C3

Chắc năng

Ghi chú

VCC (3.3)

3.3V hoặc 5V

Cấp nguồn cho màn hình.

Nguồn vào từ USB qua ESP32 có thể đẩy ra thành 2 nguồn 3.3V hoặc 5V.

GND

GND

Nối đất

Tạo một điểm tham chiếu chung cho toàn bộ thiết bị trên hệ thống

SCK

GPIO4

Clock (SPI)

Dùng chung với Màn hình

MOSI

GPIO6

Data out

Dùng chung với Màn hình

MISO

GPIO5

Data in

Dùng chân chuyên dụng của ESP32

CS

GPIO7

Điều khiển khi giao tiếp SPI

Chọn bất kỳ chân GPIO còn trống thuận tiện cho đi dây

Kiểm tra

platformio.ini

Trong phần thiết lập này chúng ta cần khai báo thêm thư viện SD trong lib_deps

[env:esp32-c3-devkitm-1]
platform = platformio/espressif32 @ 6.6.0
board = esp32-c3-devkitm-1
framework = arduino
platform_packages =
  framework-arduinoespressif32 @ ~3.20014.0
lib_deps = 
	SD // Khai báo thêm thư viện này
	SPI
	bodmer/TFT_eSPI@^2.5.43
monitor_speed = 115200
build_flags = 
	-D ARDUINO_USB_MODE=1
	-D ARDUINO_USB_CDC_ON_BOOT=1

Code and Test

#include <Arduino.h>
#include <TFT_eSPI.h>
#include <SD.h> // Thêm khai báo thư viện

// Tạo đối tượng tft từ thư viện // Để hiển thị kết quả test
TFT_eSPI tft = TFT_eSPI();

// Khai báo phần cứng cho SDCard
const int SDCARD_PIN_CS = 7;
const int SDCARD_PIN_SCK = 4;
const int SDCARD_PIN_MISO = 5;
const int SDCARD_PIN_MOSI = 6;

// Khai báo hàm
void initTFT(); // Khởi tạo màn hình
void initSD(); // Khởi tạo SDCard
void listDir(fs::FS &fs, const char * dirname, uint8_t levels); // Hàm hiển thị các tệp trong SD // Dùng để test chưa cần quan tâm nhiều

void setup() {
  initTFT();
  initSD();
}

int count = 0;
void loop() {}

void initTFT()
{
  tft.init(); 
  tft.setRotation(0);
  tft.fillScreen(TFT_BLACK);
  tft.setTextColor(TFT_GREEN);
  tft.setTextSize(1);
  tft.setCursor(0, 0);
  tft.println("Init TFT success!!!");
}

void initSD()
{
  SPI.end();
  SPI.begin(SDCARD_PIN_SCK, SDCARD_PIN_MISO, SDCARD_PIN_MOSI, SDCARD_PIN_CS); // Khởi tạo giao tiếp SPI

  tft.print("Initializing SD card using CS pin: ");
  tft.println(SDCARD_PIN_CS);

  if (!SD.begin(SDCARD_PIN_CS, SPI)) {
    tft.setTextColor(TFT_RED);
    tft.println("SD mount failed (wiring/freq).");
    return;
  }

  tft.setTextColor(TFT_GREEN);
  tft.println("SD card initialized.");

  uint8_t type = SD.cardType();
  if (type == CARD_NONE) {
    tft.setTextColor(TFT_RED);
    tft.println("No SD card detected.");
    return;
  }
  tft.printf("Type: %s\n", type == CARD_MMC ? "MMC" :
                         type == CARD_SD  ? "SDSC" :
                         type == CARD_SDHC? "SDHC/SDXC" : "UNKNOWN");
  tft.printf("Size: %llu MB\n", SD.cardSize() / (1024ULL * 1024ULL));

  tft.println("Filesystem Content:");
  listDir(SD, "/", 0);
  tft.println("\n--- Test Complete ---");
}

// Hàm liệt kê nội dung thư mục (lấy từ ví dụ của thư viện SD)
void listDir(fs::FS &fs, const char * dirname, uint8_t levels) {
  tft.printf("Listing directory: %s\n", dirname);

  File root = fs.open(dirname);
  if (!root) {
    tft.println("Failed to open directory");
    return;
  }
  if (!root.isDirectory()) {
    tft.println("Not a directory");
    return;
  }

  File file = root.openNextFile();
  while (file) {
    if (file.isDirectory()) {
      tft.print("  DIR : ");
      tft.println(file.name());
      if (levels) {
        listDir(fs, file.path(), levels - 1);
      }
    } else {
      tft.print("  FILE: ");
      tft.print(file.name());
      tft.print("\tSIZE: ");
      tft.println(file.size());
    }
    file = root.openNextFile();
  }
}

Upload and Monitor

Kết quả hiển thị như hình dưới (hoặc tương tự toàn màu green) là OK

Nếu chỉ hiển thị đến "Initializing SD card using CS pin: " thì cần check thêm terminal để kiểm tra lỗi

1000048897.jpg